sequenceModule -- builds a graded R[t]-module from a sequence of maps

Synopsis

Usage:

sequenceModule(Q, L)
Inputs:
- Q, a ring, of the form R[t]; if omitted, a suitable ring is supplied
- L, a list, of maps $(A_0 \to A_1, A_1 \to A_2, ..., A_{k-1} \to A_k)$
Outputs:
- M, a module, with an action of Q

Description

The module M is concentrated in nonnegative degrees. For $0 \le n \le k$, we have

$M_n \cong A_n$.

For $n \ge k$, the module is constant

$M_n \cong A_k$.

The variable t acts by the supplied maps in the range $0 \le n \le k$, and by the identity past degree k.

i1 : R = QQ[x]

o1 = R

o1 : PolynomialRing

i2 : Q = R[t]

o2 = Q

o2 : PolynomialRing

i3 : m1 = random(R^{-3,-4,-5},R^{-6,-7,-8})

o3 = {3} | 8x3 7x4 3x5 |
     {4} | 3x2 x3  8x4 |
     {5} | 8x  7x2 3x3 |

             3       3
o3 : Matrix R  <--- R

i4 : m2 = random(R^{0,-1,-2},R^{-3,-4,-5})

o4 = {0} | 8x3 8x4 2x5 |
     {1} | 3x2 5x3 5x4 |
     {2} | 3x  6x2 7x3 |

             3       3
o4 : Matrix R  <--- R

i5 : M = sequenceModule(Q,{m1,m2})

o5 = cokernel {0, 6} | t    0    0    0    0    0    |
              {0, 7} | 0    t    0    0    0    0    |
              {0, 8} | 0    0    t    0    0    0    |
              {1, 3} | -8x3 -7x4 -3x5 t    0    0    |
              {1, 4} | -3x2 -x3  -8x4 0    t    0    |
              {1, 5} | -8x  -7x2 -3x3 0    0    t    |
              {2, 0} | 0    0    0    -8x3 -8x4 -2x5 |
              {2, 1} | 0    0    0    -3x2 -5x3 -5x4 |
              {2, 2} | 0    0    0    -3x  -6x2 -7x3 |

                            9
o5 : Q-module, quotient of Q

i6 : isHomogeneous M

o6 = true

Caveat

If the degree of the variable t is not 1, the above still applies, but M_n should be interpreted as the degree $n * (deg t)$ part of M.

Ways to use `sequenceModule`:

sequenceModule(List)
sequenceModule(Ring,List)

For the programmer

The object sequenceModule is a method function.